郁闷！移动硬盘老中毒！

会员74640

急求哪位大侠，有什么号方法可以尽量避免移动硬盘中毒啊！

会员698

实现原理：
　　该批处理利用WIN下不允许有重名的文件夹，先建立一个autorun.inf文件夹，这样病毒的autorun.inf文件夹就不能建立了!就能达到免疫的作用!
　　autorun.inf病毒免疫的批处理,用MD命令在每个盘下面建立一个autorun.inf文件夹,达到使所有盘免疫的作用。
　　你也可以用同样的方法,免疫一些常见的病毒!

免疫autorun类病毒，全自动批处理建立或删除autorun.inf文件夹，批处理文件内容如下：   

@echo off
mode con cols=70 lines=18
title 建立或删除autorun.inf文件夹
color 4f
cls
echo +
echo +       免疫autorun类病毒，建立或删除autorun.inf文件夹 for /XP
echo + ---------------------------------------------------------------
echo +                     
echo +      此批处理会在每个分区的根目录下建立autorun.inf\cfan.文件夹，默
echo + 认的情况下是删不掉的，但可以用这个批处理删掉。在XP下测试通过。
echo +                             
echo +                                    test    2007年12月06日
echo +
echo +         [Y] 按 Y 键建立autorun.inf文件夹免疫autorun类病毒
echo +         [D] 按 D 键删除硬盘所有分区下的autorun.inf文件夹
echo +         [Q] 按其他任意键退出
echo + -----------------------------------------------------------------
echo +                  
SET Choice=
SET /P Choice=          请选择要进行的操作：
IF /I '%Choice:~0,1%'=='y' goto md
IF /I '%Choice:~0,1%'=='d' goto del
exit
:md
for %%a in (c d e f g h i j k l m n o p q r s t u v w x y z) do del /a /f /q %%a:\autorun.inf>nul 2>nul & md %%a:\autorun.inf >nul 2>nul & %%a: >nul 2>nul & cd %%a:\autorun.inf >nul 2>nul & md cfan..\ >nul 2>nul & attrib +s +h +r %%a:\autorun.inf >nul 2>nul
cls
mode con cols=70 lines=10
color 2f
echo +
echo +
echo +
echo + 已经在各分区的根目录下建立autorun.inf\cfan.文件夹免疫autorun病毒。
echo +
echo +                       感谢使用，按任意键退出
pause>nul
exit
:del
for %%a in (c d e f g h i j k l m n o p q r s t u v w x y z) do rd /s /q %%a:\autorun.inf\cfan..\ >nul 2>nul & rd /s /q %%a:\autorun.inf >nul 2>nul
cls
mode con cols=70 lines=10
color e5
echo +
echo +
echo +
echo + 已经删除各分区的根目录下建立autorun.inf\cfan.文件夹。
echo +                         感谢使用，按任意键退出
pause>nul
exit

　　将以上的内容复制到文本文档中，另存为：“保存类型”改为“所有文件”，文件名设为“creatauto.bat”或“creatauto.cmd”（注意后缀务必不能少！）。 资源管理器中，再双击文件“creatauto.bat”或“creatauto.cmd”，即可自行建立或删除autorun.inf文件夹！

    注意：
　　这种方式建立的autorun.inf文件夹不能在资源管理器中删除！若需要删除，仍需要执行此批处理文件方可删除所建autorun.inf文件夹。
　　这种方法最好是在做完系统后就运行一次，把所有盘建立免疫文件夹。在已感染autorun病毒的机器上无效，必须先用杀毒软件清除病毒。

会员74640

专业几是不一样！谢谢！

会员74640

专业就是不一样！上面打错了！

会员149789

3L所言即是！！

会员151631

也不一定是你的硬盘的原因啊，做好先杀毒啊

会员21917

AUTORUN.INF很多杀毒软件都可以免疫了，你还是对电脑杀下毒吧

会员101251

移动盘上所有EXE文件改成EXF，所有RAR文件改成RAB，所有DLL文件改成DLI，O(∩_∩)O哈哈~，用到的时候再改过来就可以了

会员49671

建议格成NTFS，建AUTORUN.INF,取消所有权限

会员38561

不用就行咯，那有出来混，没有中毒的　啊！！！晕………………

会员194518

换个带写保护开关的硬盘盒就行了，很便宜啊