迅维网

标题: 已成功对850数显风枪进行改造，过程将陆续献上 [打印本页]

作者: 春明 时间: 2008-11-13 21:28
标题: 已成功对850数显风枪进行改造，过程将陆续献上
300元左右国产热风枪控制和显示电路一般都是能省则省，控制不稳定显示不准确。
温度控制一般是用lm324等运放构成简单移相触发可控硅进行调温。工作不稳定当然温度也不稳定。温度显示电路则是假的，它只是通过测调温电位器上的电位来显示温度，调温电位器线性差，而且最主要一点就算调温电位器保持不动风量变化时，吹出的热风温度也会相差很远，但在原来的温度显示反映不出来。

针对存在的问题，我采用以下控制改造方案：

1.采用单片机控制，通电时风量最大，延时30秒进入待机状态，关机时也让风量最大吹30秒进行手柄冷却。单片机还进行温度数据采集、处理及显示控制
2.采用3片TCA785可控硅控制电路分别控制手柄发热丝、烙铁、风机。
3.采用2片MAX6675 K型热电偶接口芯片进行温度检测。（原机的手柄和烙铁都有测温线引出，经证实是K型热电偶）
其他元件尽量利旧

已基本改造完，图纸和照片陆续更新。

但现在有个问题：发热丝和烙铁芯的温度测量是准确的，但却不能真实反映热风出口温度，一般调到能吹熔焊锡的时候温度已是七八百度了。但这个温度是真实的只是它是发热丝的温度和热风出口温度差别较大，烙铁也存在这个问题。正在想办法修正，各位有什么好办法请赐教！

作者: 测试用的帐号 时间: 2008-11-14 14:44
发热丝和出风口有温差很正常,只要测量出风口温度就可以了,或者就像楼上说的减去温差

作者: 春明 时间: 2008-11-14 20:09
标题: 部分资料
可控硅控制原理图

电源、测温及单片机

显示

主电路板

测温电路板

LED显示

作者: 春明 时间: 2008-11-16 08:51
标题: 手机照的几张照片
原来的热风部分电路板，部分元件已拆走。

原来焊台控制板

新做的控制板包括热风和焊台控制

面板

安装好的照片，测温板还没固定

刚通电时状态，只有凉风并且是最大，发热丝不工作

送凉风30秒后进入待机状态

热风部分工作

作者: sbiwupm 时间: 2008-11-16 09:45
又是一个高人。。不过自用的热风枪。温度这些有时都不太关注。凭经验去完成。。也没见有什么差错。。
我建议楼主去做BGA之方面的，，因为BGA焊接要求高一些。。

作者: sulin 时间: 2008-11-16 23:16
花了不少的时间和银子吧，简单的就换个带热偶的发热丝，然后做一个358的控制，用闭环控制，效果就好很多的，我也都改过，用一个小小的洞洞板，就10几个零件搞定

作者: 春明 时间: 2008-11-17 00:36
标题: 回复 #15 sulin 的帖子
发热丝本来就带只是没用上，我改的主要是发热丝实时温度显示、可控硅控制。钱用了不少：3块TCA785每块22、2块MAX6675没块35，PCB2块50，单片机8元。
其实钱是次要的主要在整个过程学习了不少知识：用PROTEL99设计原理图、PCB
MAX6675 K型热电偶芯片应用、单片机程序开发调试
下次想搞个BGA试试，关键是温控如果我能用单片机实现的话应该成本很低的。

作者: yzz163 时间: 2008-11-17 00:47
程序可公开吗?
用的C还是汇编,温控用的PID方式吗?

作者: 春明 时间: 2008-11-17 19:38
标题: 单片机源程序
FJKG BIT P1.2    ;风机开关控制
            FJZD BIT P1.1    ;风机最大控制
            SBKG BIT P1.0          ;手柄开关控制
            LTKG BIT P1.3    ;烙铁开关控制
            SO    BIT P3.5    ; MAX6675 SO
            SCK    BIT P3.7    ;MAX6675 SCK
            SBCS BIT P3.4    ;手柄温度片选
            LTCS BIT P3.6    ;烙铁温度片选
            SBKGZT  BIT P3.3    ;手柄开关状态
               LTKGZT  BIT P3.2    ;烙铁开关状态
            SBWDGW  EQU 30H    ;手柄温度个位BCD码
                  SBWDSW  EQU 31H    ;手柄温度十位BCD
            SBWDBW  EQU 32H    ;手柄温度百位BCD
               LTWDGW  EQU 33H    ;烙铁温度个位BCD码
            LTWDSW  EQU 34H    ;烙铁温度十位BCD
               LTWDBW  EQU 35H    ;烙铁温度百位B
            SBH    EQU 21H    ;16位手柄数据高位
            SBL    EQU 20H    ;16位手柄数据低位
            LTH    EQU 23H    ;16位烙铁数据高位
            LTL    EQU 22H    ;16位烙铁数据低位
            SBSJH EQU 45H    ;10位手柄温度高位
            SBSJL EQU 44H    ;10位手柄温度低位
            LTSJH EQU 47H    ;10位烙铁温度高位
            LTSJL EQU 46H    ;10位烙铁温度低位


            ORG 0000H
            AJMP MAIN
            ORG 0030H

      MAIN: MOV P1, #1DH ;风机关，风机最大关，手柄关，烙铁关
            MOV P3, #0FFH
            CLR 20H ;手柄开关状态初始化
            MOV 30H,#00H
                  MOV 31H,#00H
            MOV 32H,#00H
               MOV 33H,#00H
               MOV 34H,#00H
               MOV 35H,#00H

      START: MOV C, LTKGZT;根据烙铁开关状态控制烙铁开或关
            MOV LTKG,C
            MOV C, SBKGZT
            JNC  D2 ;c=0转移
            JB 20H, D2 ;BIT=1转移
            MOV 20H,C ;保存本次手柄开关状态
            SETB SBKG ;发热丝关风机最大
            CLR  FJKG
            SETB  FJZD
            MOV  2AH,#64H
   READ: MOV 2BH, #32H ;显示次数计数
   DIS: ACALL DISPLAY ;循环显示50次
            DJNZ 2BH, DIS
            MOV C, LTKGZT;根据烙铁开关状态控制烙铁开或关
            MOV LTKG,C
            ACALL READWD ;读取温度数据
            MOV C, LTKGZT;根据烙铁开关状态控制烙铁开或关
            MOV LTKG,C
            DJNZ  2AH, READ
            CLR  FJZD
            SETB FJKG
            SETB SBKG
            AJMP START
   D2:    MOV C,SBKGZT
                  MOV 20H, C
            MOV SBKG,C
            MOV FJKG,C
            CLR FJZD
            MOV 64H,#32H
            MOV C, LTKGZT;根据烙铁开关状态控制烙铁开或关
            MOV LTKG,C
   DD2: ACALL DISPLAY
            DJNZ 64H,DD2
            ACALL READWD
            AJMP START
  DISPLAY:    MOV DPTR ,#TAB ;字码表格首地址送DPTR
            MOV A, SBWDGW  ;手柄温度个位BCD码送A
            MOVC A, @A+DPTR ;取得手柄温度个位字码
            MOV P0, A
            CLR P2.5
            ACALL DELAY
            SETB P2.5
            MOV A, SBWDSW  ;手柄温度十位BCD码送A
            MOVC A, @A+DPTR ;取得手柄温度十位字码
            MOV P0, A
            CLR P2.6
            ACALL DELAY
            SETB P2.6
            MOV A, SBWDBW  ;手柄温度百位BCD码送A
            JNZ XX1
            MOV A,#0AH
         XX1: MOVC A, @A+DPTR ;取得手柄温度百位字码
            MOV P0, A
            CLR P2.7
            ACALL DELAY
            SETB P2.7
            MOV A, LTWDGW  ;烙铁温度个位BCD码送A
            MOVC A, @A+DPTR ;取得手柄温度个位字码
            MOV P0, A
            CLR P2.2
            ACALL DELAY
            SETB P2.2
            MOV A, LTWDSW  ;烙铁温度十位BCD码送A
            MOVC A, @A+DPTR ;取得手柄温度十位字码
            MOV P0, A
            CLR P2.3
            ACALL DELAY
            SETB P2.3
            MOV A, LTWDBW  ;烙铁温度百位BCD码送A
            JNZ XX2
            MOV A,#0AH
      XX2:  MOVC A, @A+DPTR ;取得手柄温度百位字码
            MOV P0, A
            CLR P2.4
            ACALL DELAY
            SETB P2.4
               RET
READWD: MOV A,#00H
            CLR SBCS
            NOP
            MOV R0,#08H
            CLR SCK
            NOP
SBREADH: MOV C,SO
            RLC A ;读D15～D8高8位数据
            SETB SCK
            NOP
            NOP
            NOP
            CLR SCK
            DJNZ R0,SBREADH
            MOV SBH,A
            MOV R0,#08H
            MOV A,#00H
SBREADL: MOV C,SO ;读D7～D0低8位数据
            RLC A
            SETB SCK
            NOP
            NOP
            NOP
            CLR SCK
               DJNZ R0,SBREADL
            MOV SBL,A
            SETB SBCS
            SETB  SCK
            CLR LTCS
            MOV A,#00H
            MOV R0,#08H
            CLR SCK
            NOP
LTREADH: MOV C,SO
            RLC A ;读D15～D8高8位数据
            SETB SCK
            NOP
            NOP
            NOP
            CLR SCK
            DJNZ R0,LTREADH
            MOV LTH,A
            MOV R0,#08H
            MOV A,#00H
LTREADL: MOV C,SO ;读D7～D0低8位数据
            RLC A
            SETB SCK
            NOP
            NOP
            NOP
            CLR SCK
                  DJNZ R0, LTREADL
            MOV LTL, A
            SETB LTCS
                        ;将16位温度读取数据转换为10位二进制表示
            MOV A,SBL
            MOV C,08H  ;21H最低位送C
            RRC A
            MOV C,09H
            RRC A
            MOV C,0AH
            RRC A
            MOV C,0BH
            RRC A
            MOV C,0CH
            RRC A
            MOV SBSJL, A
            MOV A,SBH
            SWAP A
            RRC A
            ANL A, #03H
            MOV SBSJH, A
            MOV A,LTL
            MOV C,18H  ;21H最低位送C
            RRC A
            MOV C,19H
            RRC A
            MOV C,1AH
            RRC A
            MOV C,1BH
            RRC A
            MOV C,1CH
            RRC A
            MOV LTSJL, A
            MOV A,LTH
            SWAP A
            RRC A
            ANL A, #03H
            MOV LTSJH, A
                        ;将10二进制温度值转换为用于显誓
            MOV R7,SBSJL
            MOV R6,SBSJH
      HB2:  CLR A ;ＢＣＤ码初始化
            MOV R3,A
            MOV R4,A
            MOV R5,A
            MOV R2,#10H ;转换双字节十六进制整数
   HB3: MOV A,R7  ;从高端移出待转换数的一位到CY中
            RLC A
            MOV R7,A
            MOV A,R6
            RLC A
            MOV R6,A
            MOV A,R5 ;ＢＣＤ码带进位自身相加，相当于乘２
            ADDC A,R5
            DA A    ;十进制调整
            MOV R5,A
            MOV A,R4
            ADDC A,R4
            DA A
            MOV R4,A
            MOV A,R3
            ADDC A,R3
            MOV R3,A ;双字节十六进制数的万位数不超过６，不用调整
            DJNZ R2,HB3 ;处理完１６ｂｉｔ
            MOV A,R4
            ANL A,#0FH
            MOV SBWDBW,A
            MOV A,R5
            SWAP A
            ANL A,#0FH
            MOV SBWDSW, A
            MOV A, R5
            ANL A, #0FH
            MOV SBWDGW, A
            ;烙铁温度转换
            MOV R7,LTSJL
            MOV R6,LTSJH
      HB4: CLR A ;ＢＣＤ码初始化
            MOV R3,A
            MOV R4,A
            MOV R5,A
            MOV R2,#10H ;转换双字节十六进制整数
         HB5: MOV A,R7  ;从高端移出待转换数的一位到CY中
               RLC A
               MOV R7,A
               MOV A,R6
               RLC A
               MOV R6,A
               MOV A,R5 ;ＢＣＤ码带进位自身相加，相当于乘２
               ADDC A,R5
               DA A    ;十进制调整
               MOV R5,A
               MOV A,R4
               ADDC A,R4
               DA A
               MOV R4,A
               MOV A,R3
               ADDC A,R3
               MOV R3,A ;双字节十六进制数的万位数不超过６，不用调整
               DJNZ R2,HB5 ;处理完１６ｂｉｔ
               MOV A,R4
               ANL A, #0FH
               MOV LTWDBW,A
               MOV A,R5
               SWAP A
               ANL A,#0FH
               MOV LTWDSW, A
               MOV A, R5
               ANL A, #0FH
               MOV LTWDGW, A
               RET
   DELAY:  MOV 60H, #0FFH
      DD1:  DJNZ 60H, DD1
               RET
      TAB: DB 01H,4FH,12H,06H,4CH,24H,20H,0FH,00H,04H,0FFH
            END

作者: 百度uPDVS 时间: 2021-8-20 20:32
提示: 作者被禁止或删除内容自动屏蔽

欢迎光临迅维网 (https://www.chinafix.com/)